作者：电脑信息网日期：
返回目录：设置问题
好像没有
@echo off & title 一键设置屏幕保护 By 依梦琴瑶
::设置屏幕保护程序路径
set ScrFile=%SystemRoot%\System32\ssText3d.scr
::设置等待时间（分钟），有效值（1-9999）
set TimeOut=15
::设置是否启用登录屏幕，1 启用，0 禁用
set Login=1
::是否立即生效，1 立即（系统将会注销当前帐户），其它数字下次开机后生效
set Effective=1
::如果要启用自定义三维文字，请把参数设为 1，其它数字为不启用自定义。并设置好其它相关内容e79fa5e98193e4b893e5b19e331
set EnableText3d=1
::设置三维文字显示内容
set Text3d=福建
::设置文本字体
set Font=宋体
::主执行代码，如非必要，请勿修改，以免执行出错。
>nul 2>&1 "%SystemRoot%\System32\cacls.exe" "%SystemRoot%\System32\config\SYSTEM"
if '%errorlevel%' NEQ '0' (
echo 正在请求临时管理员权限...
goto UACPrompt
) else ( goto Setting )
:UACPrompt
start "" mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
:Setting
set /a TimeOut*=60
set "Key=HKCU\Control Panel\Desktop"
reg add "%key%" /v SCRNSAVE.EXE /t REG_SZ /d "%ScrFile%" /f
reg add "%key%" /v ScreenSaveTimeOut /t REG_SZ /d "%TimeOut%" /f
reg add "%key%" /v ScreenSaverIsSecure /t REG_SZ /d "%Login%" /f
if %EnableText3d% neq 1 goto End
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Screensavers\ssText3d"
reg add "%key%" /v DisplayString /t REG_SZ /d "%Text3d%" /f
reg add "%key%" /v FontFace /t REG_SZ /d "%Font%" /f
reg add "%key%" /v DisplayTime /t REG_DWORD /d 0 /f
:End
echo, & echo,
if %Effective% equ 1 (
echo 按下任意键，系统将注销当前帐户，再次登录后，相关设置即可生效。
echo 在注销前，请先保存您尚未保存的数据，以免注销后数据丢失。
pause>nul
shutdown /l >nul 2>nul
) else (
echo 按下任意键，将直接退出脚本，但屏幕保护设置页面的参数可能不会有变化。
echo 但有可能设置已经生效，建议注销帐户或重启电脑，以便正常生效。
pause>nul
)
exit
哇哈哈，正好手上有一个之前给别人写的设置屏幕保护程序的脚本，现在按照您的要求增加了一些功能，绝对符合您的要求吧！其实三维文字中可以设置的参数，都可以实现，不过既然您没有那些需求，我就不多加入了。我最美！
其实屏保zd的参数都在注册表里
见上图，如：要修改屏保内时间可用命令
“reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v ScreenSaveTimeOut /t REG_SZ /d 180”
/d 180就是180秒（3分钟）
那么图片路径在“WallPaper”键容值下，根据需要自己修改吧
以上仅供参考